Oplossingen · hoofdstuk 29Microcontrollers programmeren in C++

• (a) int: 0 tot 1023 past niet in een byte (hoogstens 255).
• (b) unsigned long: millis() is een unsigned long; in een int loopt het na 32,8 s over.
• (c) byte (0-255 past precies) of int: een int kost één byte meer maar rekent makkelijker.
• (d) bool: alleen waar of onwaar.
• (e) float: een kommagetal.
• (f) 5 jaar is ongeveer 43 830 uur: te veel voor een int (32 767), wel voor een unsigned int (65 535, genoeg voor 7,5 jaar). Wie verder wil tellen, neemt unsigned long.
• (g) long: tot 100 × 1023 = 102 300, meer dan een int of unsigned int kan bevatten.
• (h) byte: een I²C-adres heeft 7 bits.

Uitvoer in de simulatie van de Mega:

2
2.50
2
144
-5536
0.00
25.0

10 / 4 is een gehele deling (2); met (float)b rekent C++ in float (2.50). 10 % 4 is de rest (2). Een byte gaat van 400 naar 400 − 256 = 144. 30 000 + 30 000 = 60 000 past niet in een int: 60 000 − 65 536 = −5536. (5 / 9) is een gehele deling en dus 0, en 0 maal 45 blijft 0.00. Met 5.0 wordt het 25,0 (de omrekening van 77 °F naar °C).

• vlotter: D2, INPUT_PULLUP, digitalRead, HIGH = te weinig water (LOW = genoeg)
• knop S1: D22, INPUT, digitalRead, HIGH = ingedrukt
• eindeloop dicht: D24, INPUT_PULLUP, digitalRead, HIGH = dak dicht (of draad los)
• lichtsensor: A1, geen pinMode nodig, analogRead, 0 tot 1023
• groeilampen: D5, OUTPUT, analogWrite, 0 tot 255 (PWM)
• pomp: D9, OUTPUT, digitalWrite, HIGH = aan
• statusled: D13, OUTPUT, digitalWrite, HIGH = aan

De compiler (g++, zelfde kern als in de Arduino-IDE):

wb_fouten: In function 'void loop()':
wb_fouten:14:3: error: expected ',' or ';' before 'if'
wb_fouten:18:18: error: lvalue required as left operand of assignment
wb_fouten:21:3: error: 'digitalwrite' was not declared in this scope; did you mean 'digitalWrite'?
wb_fouten:13:17: warning: unused variable 'nu' [-Wunused-variable]

(1) regel 13: puntkomma na millis() vergeten; de melding staat op regel 14, want pas bij if merkt de compiler dat de opdracht niet af is. (2) regel 18: = in plaats van ==; hier weigert de compiler, omdat je aan een functieresultaat niets kan toekennen. (3) regel 21: digitalwrite met kleine w.

Verbeterd en getest:

// pomp_test.ino - verbeterd
const int POMP = 9;
const int VLOTTER = 2;
bool aan = false;
unsigned long vorige = 0;

void setup() {
  pinMode(POMP, OUTPUT);                        // fout 4: zonder pinMode geen stevige uitgang
  pinMode(VLOTTER, INPUT_PULLUP);
  Serial.begin(115200);                         // fout 5: dezelfde snelheid als de seriële monitor
}

void loop() {
  unsigned long nu = millis();                  // fout 1: puntkomma
  if (nu - vorige >= 5000) {
    vorige += 5000;
    aan = !aan;
    Serial.println(aan ? "pomp aan" : "pomp uit");   // alleen bij een wissel iets sturen
  }
  if (digitalRead(VLOTTER) == HIGH) {           // fout 2: == vergelijkt, = kent toe
    aan = false;
  }
  digitalWrite(POMP, aan ? HIGH : LOW);         // fout 3: hoofdletter W
}

In de simulatie (20 s, vlotter open van 12 tot 13 s):

pomp aan
pomp uit
pomp aan
pomp uit

Er is geen melding 'pomp uit' door de vlotter, omdat de melding alleen bij de wissel om de 5 s komt: een uitbreiding voor wie wil.

Getest met een gesimuleerde SHT31 die opwarmt:

// plotter_sht.ino - temperatuur en vocht van de kaslucht in de seriële plotter
#include <Wire.h>
#include <Adafruit_SHT31.h>

Adafruit_SHT31 sht = Adafruit_SHT31();
unsigned long vorige = 0;

void setup() {
  Serial.begin(115200);
  sht.begin(0x44);
}

void loop() {
  unsigned long nu = millis();
  if (nu - vorige >= 1000) {
    vorige += 1000;
    float t, rv;
    sht.readBoth(&t, &rv);
    Serial.print("temperatuur:");
    Serial.print(t, 1);
    Serial.print(",vocht:");
    Serial.print(rv, 1);
    Serial.println(",grens_26C:26");
  }
}

temperatuur:24.9,vocht:70.2,grens_26C:26
temperatuur:25.2,vocht:69.4,grens_26C:26
temperatuur:25.5,vocht:68.6,grens_26C:26
temperatuur:25.8,vocht:67.8,grens_26C:26
temperatuur:26.1,vocht:67.0,grens_26C:26

Getest: het bodemvocht begint op 33 % en daalt 5 procentpunt per uur (het model uit F23); een beurt geeft +16.

// water_geven_millis.ino - water geven in de meetkas zonder delay() (Arduino Uno, pinnen uit hoofdstuk 25)
const int SENSOR = A0;
const int VLOTTER = 3;
const int POMP = 6;
const int ROOD = 10;
const int GROEN = 11;
const int DROOG = 600;
const int NAT = 300;
const int DREMPEL = 30;
const unsigned long POMP_MS = 30000UL;       // 30 s pompen = 240 mL
const unsigned long WACHT_MS = 900000UL;     // daarna 15 min wachten tot het water ingezakt is

enum Fase { KLAAR, POMPEN, WACHTEN };
Fase fase = KLAAR;
unsigned long startFase = 0;

void setup() {
  pinMode(VLOTTER, INPUT_PULLUP);
  pinMode(POMP, OUTPUT);
  pinMode(ROOD, OUTPUT);
  pinMode(GROEN, OUTPUT);
  Serial.begin(115200);
}

void loop() {
  unsigned long nu = millis();
  int vocht = map(analogRead(SENSOR), DROOG, NAT, 0, 100);
  bool water = (digitalRead(VLOTTER) == LOW);

  if (fase == KLAAR && vocht < DREMPEL && water) {
    fase = POMPEN;                           // droog en er is water: een beurt begint
    startFase = nu;
    digitalWrite(POMP, HIGH);
    Serial.print(nu / 1000);
    Serial.println(" s: pomp aan");
  } else if (fase == POMPEN && (nu - startFase >= POMP_MS || !water)) {
    fase = WACHTEN;                          // 30 s voorbij, of het reservoir is leeg
    startFase = nu;
    digitalWrite(POMP, LOW);
    Serial.print(nu / 1000);
    Serial.println(" s: pomp uit, 15 min wachten");
  } else if (fase == WACHTEN && nu - startFase >= WACHT_MS) {
    fase = KLAAR;
  }

  digitalWrite(ROOD, vocht < DREMPEL ? HIGH : LOW);    // het lampje reageert nu meteen
  digitalWrite(GROEN, vocht < DREMPEL ? LOW : HIGH);
}

2537 s: pomp aan
2567 s: pomp uit, 15 min wachten

In deze drie uur valt het vocht één keer onder 30 %; na de beurt zit het op ruim 45 % en duurt het meer dan drie uur voor het weer zakt. Het lampje wordt in elke ronde bijgewerkt.

Als losse test (in klimaat.ino laat je de declaraties weg die er al zijn):

// co2_taak.ino - de CO2-klep: overdag om het halfuur 30 s open, maar niet als het dak openstaat
#include "pinnen.h"

const int START_UUR = 6;
const unsigned long CO2_PERIODE_MS = 30UL * 60 * 1000;
const unsigned long CO2_OPEN_MS = 30000UL;
unsigned long startCo2 = 0;
bool klepOpen = false;
bool dakOpen = false;                        // in klimaat.ino houdt taakDak dit bij

unsigned long secondenVanDeDag(unsigned long nu) {
  return (START_UUR * 3600UL + nu / 1000) % 86400UL;
}

void taakCo2(unsigned long nu) {
  if (nu - startCo2 >= CO2_PERIODE_MS) startCo2 += CO2_PERIODE_MS;
  unsigned long uur = secondenVanDeDag(nu) / 3600;
  bool licht = uur >= 6 && uur < 22;                  // CO2 helpt alleen als de planten licht krijgen
  bool open = licht && !dakOpen && (nu - startCo2) < CO2_OPEN_MS;
  if (open != klepOpen) {
    klepOpen = open;
    Serial.print(nu / 1000);
    Serial.println(open ? " s: CO2-klep open" : " s: CO2-klep dicht");
  }
  digitalWrite(CO2_KLEP, open ? HIGH : LOW);
}

void setup() {
  pinMode(CO2_KLEP, OUTPUT);
  Serial.begin(115200);
}

void loop() {
  taakCo2(millis());
}

De eerste 95 minuten na 06:00 in de simulatie:

0 s: CO2-klep open
30 s: CO2-klep dicht
1800 s: CO2-klep open
1830 s: CO2-klep dicht
3600 s: CO2-klep open
3630 s: CO2-klep dicht
5400 s: CO2-klep open
5430 s: CO2-klep dicht

Druk n, r, r / 10000 en invT af:

float temperatuur() {
  int n = analogRead(NTC);
  Serial.print("n = ");
  Serial.print(n);
  long r = 10000L * (1024 - n) / n;
  Serial.print("   r = ");
  Serial.print(r);
  Serial.print("   r / 10000 = ");
  Serial.print(r / 10000);
  float invT = 1.0 / 298.15 + log(r / 10000) / 3950;
  Serial.print("   invT = ");
  Serial.println(invT, 6);
  return 1.0 / invT - 273.15;
}

Uitvoer bij 18, 20, 25 en 29 °C:

n = 431   r = 13758   r / 10000 = 1   invT = 0.003354
25.00
n = 454   r = 12555   r / 10000 = 1   invT = 0.003354
25.00
n = 512   r = 10000   r / 10000 = 1   invT = 0.003354
25.00
n = 560   r = 8285   r / 10000 = 0   invT = inf
-273.15

Reken in float:

float temperatuur() {
  int n = analogRead(NTC);
  float r = 10000.0 * (1024 - n) / n;            // 10000.0: de hele berekening in float
  float invT = 1.0 / 298.15 + log(r / 10000.0) / 3950.0;
  return 1.0 / invT - 273.15;
}

Uitvoer:

17.99
19.97
25.00
29.29

// sensoren.h - wat de sensorfuncties van de klimaatmodule doen (de declaraties)
#ifndef SENSOREN_H
#define SENSOREN_H

int gemiddeld(int pin);          // 16 metingen van een analoge pin, gemiddeld
float daglichtLux();             // daglicht in lux (LDR op A1)
float batterijspanning();        // V (deler op A3)
float batterijstroom();          // A, positief = ontladen (ACS712 op A4)
float reservoirTemperatuur();    // graden C (NTC op A0)

#endif

Het moet Arduino.h invoegen (voor analogRead, micros, pow, log, NAN: in een .ino doet de IDE dat zelf, in een .cpp niet) en pinnen.h (voor LDR, BATTERIJ …), en voor de zekerheid sensoren.h, zodat de compiler controleert of declaratie en definitie overeenkomen.

// sensoren.cpp - hoe de sensorfuncties het doen (de definities)
#include <Arduino.h>
#include "pinnen.h"
#include "sensoren.h"

int gemiddeld(int pin) {
  long som = 0;
  for (int i = 0; i < 16; i++) som += analogRead(pin);
  return som / 16;
}

float daglichtLux() {
  int n = gemiddeld(LDR);
  if (n < 1) n = 1;
  float r = 1000.0 * (1024.0 - n) / n;
  return 10.0 * pow(r / 15000.0, -1.0 / 0.7) / 0.10;
}

float batterijspanning() {
  return gemiddeld(BATTERIJ) * 5.0 / 1024.0 * (133.0 / 33.0);
}

float batterijstroom() {
  long som = 0;
  unsigned long t0 = micros();
  for (int i = 0; i < 100; i++) {
    while (micros() - t0 < i * 204UL) {
    }
    som += analogRead(STROOM);
  }
  return (som / 100.0 * 5.0 / 1024.0 - 2.50) / 0.100;
}

float reservoirTemperatuur() {
  int n = gemiddeld(NTC);
  if (n < 5 || n > 1018) return NAN;                 // draad los of kortsluiting
  float r = 10000.0 * (1024.0 - n) / n;
  return 1.0 / (1.0 / 298.15 + log(r / 10000.0) / 3913.0) - 273.15;   // B na ijking (hoofdstuk 22)
}

Een testschets:

// sensoren_test.ino - de eigen bibliotheek gebruiken
#include "pinnen.h"
#include "sensoren.h"

void setup() {
  Serial.begin(115200);
  Serial.print("reservoir ");
  Serial.print(reservoirTemperatuur(), 1);
  Serial.print(" C, daglicht ");
  Serial.print(daglichtLux(), 0);
  Serial.print(" lx, batterij ");
  Serial.print(batterijspanning(), 2);
  Serial.print(" V, ");
  Serial.print(batterijstroom(), 1);
  Serial.println(" A");
}

void loop() {
}

reservoir 19.9 C, daglicht 4004 lx, batterij 13.19 V, 1.4 A